04p2_linear_parametrizations_1D.f90

Go to the documentation of this file.

!----------------------------------------------------------------------------------------
!
! This file is part of EFTCAMB.
!
! Copyright (C) 2013-2016 by the EFTCAMB authors
!
! The EFTCAMB code is free software;
! You can use it, redistribute it, and/or modify it under the terms
! of the GNU General Public License as published by the Free Software Foundation;
! either version 3 of the License, or (at your option) any later version.
! The full text of the license can be found in the file eftcamb/LICENSE at
! the top level of the EFTCAMB distribution.
!
!----------------------------------------------------------------------------------------



!----------------------------------------------------------------------------------------


module eftcamb_linear_parametrizations_1d

    use precision
    use amlutils
    use eft_def
    use eftcamb_cache
    use eftcamb_abstract_parametrizations_1d

    implicit none

    private

    public linear_parametrization_1d

    ! ---------------------------------------------------------------------------------------------
    type, extends ( parametrized_function_1d ) :: linear_parametrization_1d

        real(dl) :: linear_value

    contains

        ! utility functions:
        procedure :: set_param_number      => linearparametrized1dsetparamnumber      
        procedure :: init_parameters       => linearparametrized1dinitparams          
        procedure :: parameter_value       => linearparametrized1dparametervalues     
        procedure :: feedback              => linearparametrized1dfeedback            

        ! evaluation procedures:
        procedure :: value                 => linearparametrized1dvalue               
        procedure :: first_derivative      => linearparametrized1dfirstderivative     
        procedure :: second_derivative     => linearparametrized1dsecondderivative    
        procedure :: third_derivative      => linearparametrized1dthirdderivative     
        procedure :: integral              => linearparametrized1dintegral            

    end type linear_parametrization_1d

contains

    ! ---------------------------------------------------------------------------------------------
    ! Implementation of the linear function.
    ! ---------------------------------------------------------------------------------------------

    ! ---------------------------------------------------------------------------------------------
    subroutine linearparametrized1dsetparamnumber( self )

        implicit none

        class(linear_parametrization_1d) :: self

        ! initialize the number of parameters:
        self%parameter_number = 1

    end subroutine linearparametrized1dsetparamnumber

    ! ---------------------------------------------------------------------------------------------
    subroutine linearparametrized1dinitparams( self, array )

        implicit none

        class(linear_parametrization_1d)                        :: self
        real(dl), dimension(self%parameter_number), intent(in)  :: array

        self%linear_value = array(1)

    end subroutine linearparametrized1dinitparams

    ! ---------------------------------------------------------------------------------------------
    subroutine linearparametrized1dparametervalues( self, i, value )

        implicit none

        class(linear_parametrization_1d) :: self
        integer     , intent(in)         :: i
        real(dl)    , intent(out)        :: value

        select case (i)
            case(1)
                value = self%linear_value
            case default
                write(*,*) 'Illegal index for parameter_names.'
                write(*,*) 'Maximum value is:', self%parameter_number
                call mpistop('EFTCAMB error')
        end select

    end subroutine linearparametrized1dparametervalues

    ! ---------------------------------------------------------------------------------------------
    subroutine linearparametrized1dfeedback( self, print_params )

        implicit none

        class(linear_parametrization_1d)    :: self
        logical, optional                   :: print_params

        integer                             :: i
        real(dl)                            :: param_value
        character(len=EFT_names_max_length) :: param_name
        logical                             :: print_params_temp

        if ( present(print_params) ) then
            print_params_temp = print_params
        else
            print_params_temp = .true.
        end if

        write(*,*)     'Linear function: ', self%name
        if ( print_params_temp ) then
            do i=1, self%parameter_number
                call self%parameter_names( i, param_name  )
                call self%parameter_value( i, param_value )
                write(*,'(a23,a,F12.6)') param_name, '=', param_value
            end do
        end if

    end subroutine linearparametrized1dfeedback

    ! ---------------------------------------------------------------------------------------------
    function linearparametrized1dvalue( self, x, eft_cache )

        implicit none

        class(linear_parametrization_1d)                   :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: linearparametrized1dvalue

        linearparametrized1dvalue = self%linear_value*x

    end function linearparametrized1dvalue

    ! ---------------------------------------------------------------------------------------------
    function linearparametrized1dfirstderivative( self, x, eft_cache )

        implicit none

        class(linear_parametrization_1d)                   :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: linearparametrized1dfirstderivative

        linearparametrized1dfirstderivative = self%linear_value

    end function linearparametrized1dfirstderivative

    ! ---------------------------------------------------------------------------------------------
    function linearparametrized1dsecondderivative( self, x, eft_cache )

        implicit none

        class(linear_parametrization_1d)                   :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: linearparametrized1dsecondderivative

        linearparametrized1dsecondderivative = 0._dl

    end function linearparametrized1dsecondderivative

    ! ---------------------------------------------------------------------------------------------
    function linearparametrized1dthirdderivative( self, x, eft_cache )

        implicit none

        class(linear_parametrization_1d)                   :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: linearparametrized1dthirdderivative

        linearparametrized1dthirdderivative = 0._dl

    end function linearparametrized1dthirdderivative

    ! ---------------------------------------------------------------------------------------------
    function linearparametrized1dintegral( self, x, eft_cache )

        implicit none

        class(linear_parametrization_1d)                   :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: linearparametrized1dintegral

        linearparametrized1dintegral = exp(-3._dl*(x-1._dl)*self%linear_value)/x

    end function linearparametrized1dintegral

    ! ---------------------------------------------------------------------------------------------

end module eftcamb_linear_parametrizations_1d

!----------------------------------------------------------------------------------------