04p3_power_law_parametrizations_1D.f90

Go to the documentation of this file.

!----------------------------------------------------------------------------------------
!
! This file is part of EFTCAMB.
!
! Copyright (C) 2013-2016 by the EFTCAMB authors
!
! The EFTCAMB code is free software;
! You can use it, redistribute it, and/or modify it under the terms
! of the GNU General Public License as published by the Free Software Foundation;
! either version 3 of the License, or (at your option) any later version.
! The full text of the license can be found in the file eftcamb/LICENSE at
! the top level of the EFTCAMB distribution.
!
!----------------------------------------------------------------------------------------



!----------------------------------------------------------------------------------------


module eftcamb_power_law_parametrizations_1d

    use precision
    use amlutils
    use eft_def
    use eftcamb_cache
    use eftcamb_abstract_parametrizations_1d

    implicit none

    private

    public power_law_parametrization_1d

    ! ---------------------------------------------------------------------------------------------
    type, extends ( parametrized_function_1d ) :: power_law_parametrization_1d

        real(dl) :: coefficient
        real(dl) :: exponent

    contains

        ! utility functions:
        procedure :: set_param_number      => powerlawparametrized1dsetparamnumber      
        procedure :: init_parameters       => powerlawparametrized1dinitparams          
        procedure :: parameter_value       => powerlawparametrized1dparametervalues     
        procedure :: feedback              => powerlawparametrized1dfeedback            

        ! evaluation procedures:
        procedure :: value                 => powerlawparametrized1dvalue               
        procedure :: first_derivative      => powerlawparametrized1dfirstderivative     
        procedure :: second_derivative     => powerlawparametrized1dsecondderivative    
        procedure :: third_derivative      => powerlawparametrized1dthirdderivative     
        procedure :: integral              => powerlawparametrized1dintegral            

    end type power_law_parametrization_1d

contains

    ! ---------------------------------------------------------------------------------------------
    ! Implementation of the power law function.
    ! ---------------------------------------------------------------------------------------------

    ! ---------------------------------------------------------------------------------------------
    subroutine powerlawparametrized1dsetparamnumber( self )

        implicit none

        class(power_law_parametrization_1d) :: self

        ! initialize the number of parameters:
        self%parameter_number = 2

    end subroutine powerlawparametrized1dsetparamnumber

    ! ---------------------------------------------------------------------------------------------
    subroutine powerlawparametrized1dinitparams( self, array )

        implicit none

        class(power_law_parametrization_1d)                     :: self
        real(dl), dimension(self%parameter_number), intent(in)  :: array

        self%coefficient = array(1)
        self%exponent = array(2)

    end subroutine powerlawparametrized1dinitparams

    ! ---------------------------------------------------------------------------------------------
    subroutine powerlawparametrized1dparametervalues( self, i, value )

        implicit none

        class(power_law_parametrization_1d) :: self
        integer     , intent(in)            :: i
        real(dl)    , intent(out)           :: value

        select case (i)
            case(1)
                value = self%coefficient
            case(2)
                value = self%exponent
            case default
                write(*,*) 'Illegal index for parameter_names.'
                write(*,*) 'Maximum value is:', self%parameter_number
                call mpistop('EFTCAMB error')
        end select

    end subroutine powerlawparametrized1dparametervalues

    ! ---------------------------------------------------------------------------------------------
    subroutine powerlawparametrized1dfeedback( self, print_params )

        implicit none

        class(power_law_parametrization_1d) :: self
        logical, optional                   :: print_params

        integer                             :: i
        real(dl)                            :: param_value
        character(len=EFT_names_max_length) :: param_name
        logical                             :: print_params_temp

        if ( present(print_params) ) then
            print_params_temp = print_params
        else
            print_params_temp = .true.
        end if

        write(*,*)     'Power Law function: ', self%name
        if ( print_params_temp ) then
            do i=1, self%parameter_number
                call self%parameter_names( i, param_name  )
                call self%parameter_value( i, param_value )
                write(*,'(a23,a,F12.6)') param_name, '=', param_value
            end do
        end if

    end subroutine powerlawparametrized1dfeedback

    ! ---------------------------------------------------------------------------------------------
    function powerlawparametrized1dvalue( self, x, eft_cache )

        implicit none

        class(power_law_parametrization_1d)                :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: powerlawparametrized1dvalue

        powerlawparametrized1dvalue = self%coefficient*x**self%exponent

    end function powerlawparametrized1dvalue

    ! ---------------------------------------------------------------------------------------------
    function powerlawparametrized1dfirstderivative( self, x, eft_cache )

        implicit none

        class(power_law_parametrization_1d)                :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: powerlawparametrized1dfirstderivative

        powerlawparametrized1dfirstderivative = self%coefficient*self%exponent*x**(self%exponent-1._dl)

    end function powerlawparametrized1dfirstderivative

    ! ---------------------------------------------------------------------------------------------
    function powerlawparametrized1dsecondderivative( self, x, eft_cache )

        implicit none

        class(power_law_parametrization_1d)                :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: powerlawparametrized1dsecondderivative

        powerlawparametrized1dsecondderivative = self%coefficient*self%exponent*(self%exponent-1._dl)*x**(self%exponent-2._dl)

    end function powerlawparametrized1dsecondderivative

    ! ---------------------------------------------------------------------------------------------
    function powerlawparametrized1dthirdderivative( self, x, eft_cache )

        implicit none

        class(power_law_parametrization_1d)                :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: powerlawparametrized1dthirdderivative

        powerlawparametrized1dthirdderivative = self%coefficient*self%exponent*(self%exponent-1._dl)*(self%exponent-2._dl)*x**(self%exponent-3._dl)

    end function powerlawparametrized1dthirdderivative

    ! ---------------------------------------------------------------------------------------------
    function powerlawparametrized1dintegral( self, x, eft_cache )

        implicit none

        class(power_law_parametrization_1d)                :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: powerlawparametrized1dintegral

        if ( self%exponent == 0. ) then
            powerlawparametrized1dintegral = x**(-1._dl -3._dl*self%coefficient)
        else
            powerlawparametrized1dintegral = 1._dl/(x*exp((3._dl*(-1._dl + x**self%exponent)*self%coefficient)/self%exponent))
        end if

    end function powerlawparametrized1dintegral

    ! ---------------------------------------------------------------------------------------------

end module eftcamb_power_law_parametrizations_1d

!----------------------------------------------------------------------------------------