04p4_exponential_parametrizations_1D.f90

Go to the documentation of this file.

!----------------------------------------------------------------------------------------
!
! This file is part of EFTCAMB.
!
! Copyright (C) 2013-2016 by the EFTCAMB authors
!
! The EFTCAMB code is free software;
! You can use it, redistribute it, and/or modify it under the terms
! of the GNU General Public License as published by the Free Software Foundation;
! either version 3 of the License, or (at your option) any later version.
! The full text of the license can be found in the file eftcamb/LICENSE at
! the top level of the EFTCAMB distribution.
!
!----------------------------------------------------------------------------------------



!----------------------------------------------------------------------------------------


module eftcamb_exponential_parametrizations_1d

    use precision
    use amlutils
    use eft_def
    use eftcamb_cache
    use eftcamb_abstract_parametrizations_1d

    implicit none

    private

    public exponential_parametrization_1d

    ! ---------------------------------------------------------------------------------------------
    type, extends ( parametrized_function_1d ) :: exponential_parametrization_1d

        real(dl) :: coefficient
        real(dl) :: exponent

    contains

        ! utility functions:
        procedure :: set_param_number      => exponentialparametrized1dsetparamnumber      
        procedure :: init_parameters       => exponentialparametrized1dinitparams          
        procedure :: parameter_value       => exponentialparametrized1dparametervalues     
        procedure :: feedback              => exponentialparametrized1dfeedback            

        ! evaluation procedures:
        procedure :: value                 => exponentialparametrized1dvalue               
        procedure :: first_derivative      => exponentialparametrized1dfirstderivative     
        procedure :: second_derivative     => exponentialparametrized1dsecondderivative    
        procedure :: third_derivative      => exponentialparametrized1dthirdderivative     
        procedure :: integral              => exponentialparametrized1dintegral            

    end type exponential_parametrization_1d

contains

    ! ---------------------------------------------------------------------------------------------
    ! Implementation of the exponential function.
    ! ---------------------------------------------------------------------------------------------

    ! ---------------------------------------------------------------------------------------------
    subroutine exponentialparametrized1dsetparamnumber( self )

        implicit none

        class(exponential_parametrization_1d) :: self

        ! initialize the number of parameters:
        self%parameter_number = 2

    end subroutine exponentialparametrized1dsetparamnumber

    ! ---------------------------------------------------------------------------------------------
    subroutine exponentialparametrized1dinitparams( self, array )

        implicit none

        class(exponential_parametrization_1d)                   :: self
        real(dl), dimension(self%parameter_number), intent(in)  :: array

        self%coefficient = array(1)
        self%exponent = array(2)

    end subroutine exponentialparametrized1dinitparams

    ! ---------------------------------------------------------------------------------------------
    subroutine exponentialparametrized1dparametervalues( self, i, value )

        implicit none

        class(exponential_parametrization_1d):: self
        integer     , intent(in)             :: i
        real(dl)    , intent(out)            :: value

        select case (i)
            case(1)
                value = self%coefficient
            case(2)
                value = self%exponent
            case default
                write(*,*) 'Illegal index for parameter_names.'
                write(*,*) 'Maximum value is:', self%parameter_number
                call mpistop('EFTCAMB error')
        end select

    end subroutine exponentialparametrized1dparametervalues

    ! ---------------------------------------------------------------------------------------------
    subroutine exponentialparametrized1dfeedback( self, print_params )

        implicit none

        class(exponential_parametrization_1d) :: self
        logical, optional                     :: print_params

        integer                               :: i
        real(dl)                              :: param_value
        character(len=EFT_names_max_length)   :: param_name
        logical                               :: print_params_temp

        if ( present(print_params) ) then
            print_params_temp = print_params
        else
            print_params_temp = .true.
        end if

        write(*,*)     'Exponential function: ', self%name
        if ( print_params_temp ) then
            do i=1, self%parameter_number
                call self%parameter_names( i, param_name  )
                call self%parameter_value( i, param_value )
                write(*,'(a23,a,F12.6)') param_name, '=', param_value
            end do
        end if

    end subroutine exponentialparametrized1dfeedback

    ! ---------------------------------------------------------------------------------------------
    function exponentialparametrized1dvalue( self, x, eft_cache )

        implicit none

        class(exponential_parametrization_1d)              :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: exponentialparametrized1dvalue

        exponentialparametrized1dvalue = exp(self%coefficient*x**self%exponent) -1._dl
    end function exponentialparametrized1dvalue

    ! ---------------------------------------------------------------------------------------------
    function exponentialparametrized1dfirstderivative( self, x, eft_cache )

        implicit none

        class(exponential_parametrization_1d)              :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: exponentialparametrized1dfirstderivative

        exponentialparametrized1dfirstderivative = self%coefficient*self%exponent*x**(self%exponent-1._dl)*exp(self%coefficient*x**self%exponent)

    end function exponentialparametrized1dfirstderivative

    ! ---------------------------------------------------------------------------------------------
    function exponentialparametrized1dsecondderivative( self, x, eft_cache )

        implicit none

        class(exponential_parametrization_1d)              :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: exponentialparametrized1dsecondderivative

        exponentialparametrized1dsecondderivative = self%coefficient*self%exponent*(self%exponent -1._dl +x**self%exponent*self%coefficient*self%exponent)*x**(self%exponent-2._dl)*exp(self%coefficient*x**self%exponent)

    end function exponentialparametrized1dsecondderivative

    ! ---------------------------------------------------------------------------------------------
    function exponentialparametrized1dthirdderivative( self, x, eft_cache )

        implicit none

        class(exponential_parametrization_1d)              :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: exponentialparametrized1dthirdderivative

        exponentialparametrized1dthirdderivative = self%coefficient*self%exponent*exp(self%coefficient*x**self%exponent)*x**(self%exponent-3._dl)&
            & *(2._dl +self%exponent*(-3._dl +self%exponent +x**self%exponent*self%coefficient*(-3._dl +self%exponent*(3._dl +x**self%exponent*self%coefficient))))

    end function exponentialparametrized1dthirdderivative

    ! ---------------------------------------------------------------------------------------------
    function exponentialparametrized1dintegral( self, x, eft_cache )

        implicit none

        class(exponential_parametrization_1d)              :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: exponentialparametrized1dintegral

        exponentialparametrized1dintegral = 0._dl

        
        write(*,*) 'ExponentialParametrized1DIntegral is not implemented.'
        write(*,*) 'Calculations cannot proceed.'
        call mpistop('EFTCAMB error')

    end function exponentialparametrized1dintegral

    ! ---------------------------------------------------------------------------------------------

end module eftcamb_exponential_parametrizations_1d

!----------------------------------------------------------------------------------------