04p5_CPL_parametrizations_1D.f90

Go to the documentation of this file.

!----------------------------------------------------------------------------------------
!
! This file is part of EFTCAMB.
!
! Copyright (C) 2013-2016 by the EFTCAMB authors
!
! The EFTCAMB code is free software;
! You can use it, redistribute it, and/or modify it under the terms
! of the GNU General Public License as published by the Free Software Foundation;
! either version 3 of the License, or (at your option) any later version.
! The full text of the license can be found in the file eftcamb/LICENSE at
! the top level of the EFTCAMB distribution.
!
!----------------------------------------------------------------------------------------



!----------------------------------------------------------------------------------------


module eftcamb_cpl_parametrizations_1d

    use precision
    use amlutils
    use eft_def
    use eftcamb_cache
    use eftcamb_abstract_parametrizations_1d

    implicit none

    private

    public cpl_parametrization_1d

    ! ---------------------------------------------------------------------------------------------
    type, extends ( parametrized_function_1d ) :: cpl_parametrization_1d

        real(dl) :: w0
        real(dl) :: wa

    contains

        ! utility functions:
        procedure :: set_param_number      => cplparametrized1dsetparamnumber      
        procedure :: init_parameters       => cplparametrized1dinitparams          
        procedure :: parameter_value       => cplparametrized1dparametervalues     
        procedure :: feedback              => cplparametrized1dfeedback            

        ! evaluation procedures:
        procedure :: value                 => cplparametrized1dvalue               
        procedure :: first_derivative      => cplparametrized1dfirstderivative     
        procedure :: second_derivative     => cplparametrized1dsecondderivative    
        procedure :: third_derivative      => cplparametrized1dthirdderivative     
        procedure :: integral              => cplparametrized1dintegral            

    end type cpl_parametrization_1d

contains

    ! ---------------------------------------------------------------------------------------------
    ! Implementation of the CPL function.
    ! ---------------------------------------------------------------------------------------------

    ! ---------------------------------------------------------------------------------------------
    subroutine cplparametrized1dsetparamnumber( self )

        implicit none

        class(cpl_parametrization_1d) :: self

        ! initialize the number of parameters:
        self%parameter_number = 2

    end subroutine cplparametrized1dsetparamnumber

    ! ---------------------------------------------------------------------------------------------
    subroutine cplparametrized1dinitparams( self, array )

        implicit none

        class(cpl_parametrization_1d)                           :: self
        real(dl), dimension(self%parameter_number), intent(in)  :: array

        self%w0 = array(1)
        self%wa = array(2)

    end subroutine cplparametrized1dinitparams

    ! ---------------------------------------------------------------------------------------------
    subroutine cplparametrized1dparametervalues( self, i, value )

        implicit none

        class(cpl_parametrization_1d)        :: self
        integer     , intent(in)             :: i
        real(dl)    , intent(out)            :: value

        select case (i)
            case(1)
                value = self%w0
            case(2)
                value = self%wa
            case default
                write(*,*) 'Illegal index for parameter_names.'
                write(*,*) 'Maximum value is:', self%parameter_number
                call mpistop('EFTCAMB error')
        end select

    end subroutine cplparametrized1dparametervalues

    ! ---------------------------------------------------------------------------------------------
    subroutine cplparametrized1dfeedback( self, print_params )

        implicit none

        class(cpl_parametrization_1d)    :: self
        logical, optional                :: print_params

        integer                               :: i
        real(dl)                              :: param_value
        character(len=EFT_names_max_length)   :: param_name
        logical                               :: print_params_temp

        if ( present(print_params) ) then
            print_params_temp = print_params
        else
            print_params_temp = .true.
        end if

        write(*,*)     'CPL parametrization: ', self%name
        if ( print_params_temp ) then
            do i=1, self%parameter_number
                call self%parameter_names( i, param_name  )
                call self%parameter_value( i, param_value )
                write(*,'(a23,a,F12.6)') param_name, '=', param_value
            end do
        end if

    end subroutine cplparametrized1dfeedback

    ! ---------------------------------------------------------------------------------------------
    function cplparametrized1dvalue( self, x, eft_cache )

        implicit none

        class(cpl_parametrization_1d)                      :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: cplparametrized1dvalue

        cplparametrized1dvalue = self%w0 +(1._dl - x)*self%wa
    end function cplparametrized1dvalue

    ! ---------------------------------------------------------------------------------------------
    function cplparametrized1dfirstderivative( self, x, eft_cache )

        implicit none

        class(cpl_parametrization_1d)                      :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: cplparametrized1dfirstderivative

        cplparametrized1dfirstderivative = -self%wa

    end function cplparametrized1dfirstderivative

    ! ---------------------------------------------------------------------------------------------
    function cplparametrized1dsecondderivative( self, x, eft_cache )

        implicit none

        class(cpl_parametrization_1d)                      :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: cplparametrized1dsecondderivative

        cplparametrized1dsecondderivative = 0._dl

    end function cplparametrized1dsecondderivative

    ! ---------------------------------------------------------------------------------------------
    function cplparametrized1dthirdderivative( self, x, eft_cache )

        implicit none

        class(cpl_parametrization_1d)                      :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: cplparametrized1dthirdderivative

        cplparametrized1dthirdderivative = 0._dl

    end function cplparametrized1dthirdderivative

    ! ---------------------------------------------------------------------------------------------
    function cplparametrized1dintegral( self, x, eft_cache )

        implicit none

        class(cpl_parametrization_1d)                      :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: cplparametrized1dintegral

        cplparametrized1dintegral = x**(2._dl -3._dl*(1._dl +self%w0 +self%wa))*exp(3._dl*(x-1._dl)*self%wa)

    end function cplparametrized1dintegral

    ! ---------------------------------------------------------------------------------------------

end module eftcamb_cpl_parametrizations_1d

!----------------------------------------------------------------------------------------