04p6_JBP_parametrizations_1D.f90

Go to the documentation of this file.

!----------------------------------------------------------------------------------------
!
! This file is part of EFTCAMB.
!
! Copyright (C) 2013-2016 by the EFTCAMB authors
!
! The EFTCAMB code is free software;
! You can use it, redistribute it, and/or modify it under the terms
! of the GNU General Public License as published by the Free Software Foundation;
! either version 3 of the License, or (at your option) any later version.
! The full text of the license can be found in the file eftcamb/LICENSE at
! the top level of the EFTCAMB distribution.
!
!----------------------------------------------------------------------------------------



!----------------------------------------------------------------------------------------


module eftcamb_jbp_parametrizations_1d

    use precision
    use amlutils
    use eft_def
    use eftcamb_cache
    use eftcamb_abstract_parametrizations_1d

    implicit none

    private

    public jbp_parametrization_1d

    ! ---------------------------------------------------------------------------------------------
    type, extends ( parametrized_function_1d ) :: jbp_parametrization_1d

        real(dl) :: w0
        real(dl) :: wa
        real(dl) :: wn

    contains

        ! utility functions:
        procedure :: set_param_number      => jbpparametrized1dsetparamnumber      
        procedure :: init_parameters       => jbpparametrized1dinitparams          
        procedure :: parameter_value       => jbpparametrized1dparametervalues     
        procedure :: feedback              => jbpparametrized1dfeedback            

        ! evaluation procedures:
        procedure :: value                 => jbpparametrized1dvalue               
        procedure :: first_derivative      => jbpparametrized1dfirstderivative     
        procedure :: second_derivative     => jbpparametrized1dsecondderivative    
        procedure :: third_derivative      => jbpparametrized1dthirdderivative     
        procedure :: integral              => jbpparametrized1dintegral            

    end type jbp_parametrization_1d

contains

    ! ---------------------------------------------------------------------------------------------
    ! Implementation of the JBP function.
    ! ---------------------------------------------------------------------------------------------

    ! ---------------------------------------------------------------------------------------------
    subroutine jbpparametrized1dsetparamnumber( self )

        implicit none

        class(jbp_parametrization_1d) :: self

        ! initialize the number of parameters:
        self%parameter_number = 3

    end subroutine jbpparametrized1dsetparamnumber

    ! ---------------------------------------------------------------------------------------------
    subroutine jbpparametrized1dinitparams( self, array )

        implicit none

        class(jbp_parametrization_1d)                           :: self
        real(dl), dimension(self%parameter_number), intent(in)  :: array

        self%w0 = array(1)
        self%wa = array(2)
        self%wn = array(3)

    end subroutine jbpparametrized1dinitparams

    ! ---------------------------------------------------------------------------------------------
    subroutine jbpparametrized1dparametervalues( self, i, value )

        implicit none

        class(jbp_parametrization_1d)        :: self
        integer     , intent(in)             :: i
        real(dl)    , intent(out)            :: value

        select case (i)
            case(1)
                value = self%w0
            case(2)
                value = self%wa
            case(3)
                value = self%wn
            case default
                write(*,*) 'Illegal index for parameter_names.'
                write(*,*) 'Maximum value is:', self%parameter_number
                call mpistop('EFTCAMB error')
        end select

    end subroutine jbpparametrized1dparametervalues

    ! ---------------------------------------------------------------------------------------------
    subroutine jbpparametrized1dfeedback( self, print_params )

        implicit none

        class(jbp_parametrization_1d)    :: self
        logical, optional                :: print_params

        integer                               :: i
        real(dl)                              :: param_value
        character(len=EFT_names_max_length)   :: param_name
        logical                               :: print_params_temp

        if ( present(print_params) ) then
            print_params_temp = print_params
        else
            print_params_temp = .true.
        end if

        write(*,*)     'Generalized JBP parametrization: ', self%name
        if ( print_params_temp ) then
            do i=1, self%parameter_number
                call self%parameter_names( i, param_name  )
                call self%parameter_value( i, param_value )
                write(*,'(a23,a,F12.6)') param_name, '=', param_value
            end do
        end if

    end subroutine jbpparametrized1dfeedback

    ! ---------------------------------------------------------------------------------------------
    function jbpparametrized1dvalue( self, x, eft_cache )

        implicit none

        class(jbp_parametrization_1d)                      :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: jbpparametrized1dvalue

        jbpparametrized1dvalue = self%w0 +(1._dl - x)*self%wa*x**(self%wn -1._dl)
    end function jbpparametrized1dvalue

    ! ---------------------------------------------------------------------------------------------
    function jbpparametrized1dfirstderivative( self, x, eft_cache )

        implicit none

        class(jbp_parametrization_1d)                      :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: jbpparametrized1dfirstderivative

        jbpparametrized1dfirstderivative = x**(-2.0_dl +self%wn)*(-1._dl +self%wn -x*self%wn)*self%wa

    end function jbpparametrized1dfirstderivative

    ! ---------------------------------------------------------------------------------------------
    function jbpparametrized1dsecondderivative( self, x, eft_cache )

        implicit none

        class(jbp_parametrization_1d)                      :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: jbpparametrized1dsecondderivative

        jbpparametrized1dsecondderivative = -x**(-3._dl +self%wn)*(-1.0_dl +self%wn)*(2._dl +self%wn*(-1._dl +x))*self%wa

    end function jbpparametrized1dsecondderivative

    ! ---------------------------------------------------------------------------------------------
    function jbpparametrized1dthirdderivative( self, x, eft_cache )

        implicit none

        class(jbp_parametrization_1d)                      :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: jbpparametrized1dthirdderivative

        jbpparametrized1dthirdderivative = -x**(-4._dl +self%wn)*(-2.0_dl +self%wn)*(-1._dl +self%wn)*(3._dl +self%wn*(-1._dl +x))*self%wa

    end function jbpparametrized1dthirdderivative

    ! ---------------------------------------------------------------------------------------------
    function jbpparametrized1dintegral( self, x, eft_cache )

        implicit none

        class(jbp_parametrization_1d)                      :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: jbpparametrized1dintegral

        jbpparametrized1dintegral = x**(-1._dl -3._dl*self%w0)*exp(3._dl*(x +x**self%wn*(x*(self%wn -1._dl) -self%wn))*self%wa/(x*self%wn*(self%wn -1._dl)))

    end function jbpparametrized1dintegral

    ! ---------------------------------------------------------------------------------------------

end module eftcamb_jbp_parametrizations_1d

!----------------------------------------------------------------------------------------