04p7_turning_point_parametrizations_1D.f90

Go to the documentation of this file.

!----------------------------------------------------------------------------------------
!
! This file is part of EFTCAMB.
!
! Copyright (C) 2013-2016 by the EFTCAMB authors
!
! The EFTCAMB code is free software;
! You can use it, redistribute it, and/or modify it under the terms
! of the GNU General Public License as published by the Free Software Foundation;
! either version 3 of the License, or (at your option) any later version.
! The full text of the license can be found in the file eftcamb/LICENSE at
! the top level of the EFTCAMB distribution.
!
!----------------------------------------------------------------------------------------



!----------------------------------------------------------------------------------------


module eftcamb_turning_point_parametrizations_1d

    use precision
    use amlutils
    use eft_def
    use eftcamb_cache
    use eftcamb_abstract_parametrizations_1d

    implicit none

    private

    public turning_point_parametrization_1d

    ! ---------------------------------------------------------------------------------------------
    type, extends ( parametrized_function_1d ) :: turning_point_parametrization_1d

        real(dl) :: w0
        real(dl) :: wa
        real(dl) :: wat

    contains

        ! utility functions:
        procedure :: set_param_number      => turningpointparametrized1dsetparamnumber      
        procedure :: init_parameters       => turningpointparametrized1dinitparams          
        procedure :: parameter_value       => turningpointparametrized1dparametervalues     
        procedure :: feedback              => turningpointparametrized1dfeedback            

        ! evaluation procedures:
        procedure :: value                 => turningpointparametrized1dvalue               
        procedure :: first_derivative      => turningpointparametrized1dfirstderivative     
        procedure :: second_derivative     => turningpointparametrized1dsecondderivative    
        procedure :: third_derivative      => turningpointparametrized1dthirdderivative     
        procedure :: integral              => turningpointparametrized1dintegral            

    end type turning_point_parametrization_1d

contains

    ! ---------------------------------------------------------------------------------------------
    ! Implementation of the turning point function.
    ! ---------------------------------------------------------------------------------------------

    ! ---------------------------------------------------------------------------------------------
    subroutine turningpointparametrized1dsetparamnumber( self )

        implicit none

        class(turning_point_parametrization_1d) :: self

        ! initialize the number of parameters:
        self%parameter_number = 3

    end subroutine turningpointparametrized1dsetparamnumber

    ! ---------------------------------------------------------------------------------------------
    subroutine turningpointparametrized1dinitparams( self, array )

        implicit none

        class(turning_point_parametrization_1d)                 :: self
        real(dl), dimension(self%parameter_number), intent(in)  :: array

        self%w0 = array(1)
        self%wa = array(2)
        self%wat= array(3)

    end subroutine turningpointparametrized1dinitparams

    ! ---------------------------------------------------------------------------------------------
    subroutine turningpointparametrized1dparametervalues( self, i, value )

        implicit none

        class(turning_point_parametrization_1d):: self
        integer     , intent(in)               :: i
        real(dl)    , intent(out)              :: value

        select case (i)
            case(1)
                value = self%w0
            case(2)
                value = self%wa
            case(3)
                value = self%wat
            case default
                write(*,*) 'Illegal index for parameter_names.'
                write(*,*) 'Maximum value is:', self%parameter_number
                call mpistop('EFTCAMB error')
        end select

    end subroutine turningpointparametrized1dparametervalues

    ! ---------------------------------------------------------------------------------------------
    subroutine turningpointparametrized1dfeedback( self, print_params )

        implicit none

        class(turning_point_parametrization_1d) :: self
        logical, optional                       :: print_params

        integer                                 :: i
        real(dl)                                :: param_value
        character(len=EFT_names_max_length)     :: param_name
        logical                                 :: print_params_temp

        if ( present(print_params) ) then
            print_params_temp = print_params
        else
            print_params_temp = .true.
        end if

        write(*,*)     'Turning Point parametrization: ', self%name
        if ( print_params_temp ) then
            do i=1, self%parameter_number
                call self%parameter_names( i, param_name  )
                call self%parameter_value( i, param_value )
                write(*,'(a23,a,F12.6)') param_name, '=', param_value
            end do
        end if

    end subroutine turningpointparametrized1dfeedback

    ! ---------------------------------------------------------------------------------------------
    function turningpointparametrized1dvalue( self, x, eft_cache )

        implicit none

        class(turning_point_parametrization_1d)            :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: turningpointparametrized1dvalue

        turningpointparametrized1dvalue = self%w0 +self%wa*(self%wat - x)**2._dl

    end function turningpointparametrized1dvalue

    ! ---------------------------------------------------------------------------------------------
    function turningpointparametrized1dfirstderivative( self, x, eft_cache )

        implicit none

        class(turning_point_parametrization_1d)            :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: turningpointparametrized1dfirstderivative

        turningpointparametrized1dfirstderivative = 2._dl*self%wa*(x -self%wat)

    end function turningpointparametrized1dfirstderivative

    ! ---------------------------------------------------------------------------------------------
    function turningpointparametrized1dsecondderivative( self, x, eft_cache )

        implicit none

        class(turning_point_parametrization_1d)            :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: turningpointparametrized1dsecondderivative

        turningpointparametrized1dsecondderivative = 2._dl*self%wa

    end function turningpointparametrized1dsecondderivative

    ! ---------------------------------------------------------------------------------------------
    function turningpointparametrized1dthirdderivative( self, x, eft_cache )

        implicit none

        class(turning_point_parametrization_1d)            :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: turningpointparametrized1dthirdderivative

        turningpointparametrized1dthirdderivative = 0._dl

    end function turningpointparametrized1dthirdderivative

    ! ---------------------------------------------------------------------------------------------
    function turningpointparametrized1dintegral( self, x, eft_cache )

        implicit none

        class(turning_point_parametrization_1d)            :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: turningpointparametrized1dintegral

        turningpointparametrized1dintegral = x**(2._dl -3._dl*(1._dl +self%w0 +self%wa*self%wat**2._dl))*exp(-1.5_dl*(x -1._dl)*self%wa*(1._dl +x -4._dl*self%wat))

    end function turningpointparametrized1dintegral

    ! ---------------------------------------------------------------------------------------------

end module eftcamb_turning_point_parametrizations_1d

!----------------------------------------------------------------------------------------