04p8_taylor_expansion_parametrizations_1D.f90

Go to the documentation of this file.

!----------------------------------------------------------------------------------------
!
! This file is part of EFTCAMB.
!
! Copyright (C) 2013-2016 by the EFTCAMB authors
!
! The EFTCAMB code is free software;
! You can use it, redistribute it, and/or modify it under the terms
! of the GNU General Public License as published by the Free Software Foundation;
! either version 3 of the License, or (at your option) any later version.
! The full text of the license can be found in the file eftcamb/LICENSE at
! the top level of the EFTCAMB distribution.
!
!----------------------------------------------------------------------------------------



!----------------------------------------------------------------------------------------


module eftcamb_taylor_parametrizations_1d

    use precision
    use amlutils
    use eft_def
    use eftcamb_cache
    use eftcamb_abstract_parametrizations_1d

    implicit none

    private

    public taylor_parametrization_1d

    ! ---------------------------------------------------------------------------------------------
    type, extends ( parametrized_function_1d ) :: taylor_parametrization_1d

        real(dl) :: w0
        real(dl) :: wa
        real(dl) :: w2
        real(dl) :: w3

    contains

        ! utility functions:
        procedure :: set_param_number      => taylorparametrized1dsetparamnumber      
        procedure :: init_parameters       => taylorparametrized1dinitparams          
        procedure :: parameter_value       => taylorparametrized1dparametervalues     
        procedure :: feedback              => taylorparametrized1dfeedback            

        ! evaluation procedures:
        procedure :: value                 => taylorparametrized1dvalue               
        procedure :: first_derivative      => taylorparametrized1dfirstderivative     
        procedure :: second_derivative     => taylorparametrized1dsecondderivative    
        procedure :: third_derivative      => taylorparametrized1dthirdderivative     
        procedure :: integral              => taylorparametrized1dintegral            

    end type taylor_parametrization_1d

contains

    ! ---------------------------------------------------------------------------------------------
    ! Implementation of the Taylor expansion parametrization.
    ! ---------------------------------------------------------------------------------------------

    ! ---------------------------------------------------------------------------------------------
    subroutine taylorparametrized1dsetparamnumber( self )

        implicit none

        class(taylor_parametrization_1d) :: self

        ! initialize the number of parameters:
        self%parameter_number = 4

    end subroutine taylorparametrized1dsetparamnumber

    ! ---------------------------------------------------------------------------------------------
    subroutine taylorparametrized1dinitparams( self, array )

        implicit none

        class(taylor_parametrization_1d)                        :: self
        real(dl), dimension(self%parameter_number), intent(in)  :: array

        self%w0 = array(1)
        self%wa = array(2)
        self%w2 = array(3)
        self%w3 = array(4)

    end subroutine taylorparametrized1dinitparams

    ! ---------------------------------------------------------------------------------------------
    subroutine taylorparametrized1dparametervalues( self, i, value )

        implicit none

        class(taylor_parametrization_1d)       :: self
        integer     , intent(in)               :: i
        real(dl)    , intent(out)              :: value

        select case (i)
            case(1)
                value = self%w0
            case(2)
                value = self%wa
            case(3)
                value = self%w2
            case(4)
                value = self%w3
            case default
                write(*,*) 'Illegal index for parameter_names.'
                write(*,*) 'Maximum value is:', self%parameter_number
                call mpistop('EFTCAMB error')
        end select

    end subroutine taylorparametrized1dparametervalues

    ! ---------------------------------------------------------------------------------------------
    subroutine taylorparametrized1dfeedback( self, print_params )

        implicit none

        class(taylor_parametrization_1d) :: self
        logical, optional                :: print_params

        integer                                 :: i
        real(dl)                                :: param_value
        character(len=EFT_names_max_length)     :: param_name
        logical                                 :: print_params_temp

        if ( present(print_params) ) then
            print_params_temp = print_params
        else
            print_params_temp = .true.
        end if

        write(*,*)     'Taylor expansion parametrization: ', self%name
        if ( print_params_temp ) then
            do i=1, self%parameter_number
                call self%parameter_names( i, param_name  )
                call self%parameter_value( i, param_value )
                write(*,'(a23,a,F12.6)') param_name, '=', param_value
            end do
        end if

    end subroutine taylorparametrized1dfeedback

    ! ---------------------------------------------------------------------------------------------
    function taylorparametrized1dvalue( self, x, eft_cache )

        implicit none

        class(taylor_parametrization_1d)                   :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: taylorparametrized1dvalue

        taylorparametrized1dvalue = self%w0 +self%wa*x +0.5_dl*self%w2*x**2 +self%w3/6._dl*x**3

    end function taylorparametrized1dvalue

    ! ---------------------------------------------------------------------------------------------
    function taylorparametrized1dfirstderivative( self, x, eft_cache )

        implicit none

        class(taylor_parametrization_1d)                   :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: taylorparametrized1dfirstderivative

        taylorparametrized1dfirstderivative = self%wa +self%w2*x +0.5_dl*self%w3*x**2


    end function taylorparametrized1dfirstderivative

    ! ---------------------------------------------------------------------------------------------
    function taylorparametrized1dsecondderivative( self, x, eft_cache )

        implicit none

        class(taylor_parametrization_1d)                   :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: taylorparametrized1dsecondderivative

        taylorparametrized1dsecondderivative = self%w2 +self%w3*x

    end function taylorparametrized1dsecondderivative

    ! ---------------------------------------------------------------------------------------------
    function taylorparametrized1dthirdderivative( self, x, eft_cache )

        implicit none

        class(taylor_parametrization_1d)                   :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: taylorparametrized1dthirdderivative

        taylorparametrized1dthirdderivative = self%w3

    end function taylorparametrized1dthirdderivative

    ! ---------------------------------------------------------------------------------------------
    function taylorparametrized1dintegral( self, x, eft_cache )

        implicit none

        class(taylor_parametrization_1d)                   :: self
        real(dl), intent(in)                               :: x
        type(eftcamb_timestep_cache), intent(in), optional :: eft_cache
        real(dl) :: taylorparametrized1dintegral

        taylorparametrized1dintegral = x**(-1._dl -3._dl*self%w0)*exp(-1._dl/12._dl*(x -1._dl)*(9._dl*(1._dl+x)*self%w2 +2._dl*(1._dl +x +x**2)*self%w3 +36._dl*self%wa))

    end function taylorparametrized1dintegral

    ! ---------------------------------------------------------------------------------------------

end module eftcamb_taylor_parametrizations_1d

!----------------------------------------------------------------------------------------