10p1_Horava.f90

Go to the documentation of this file.

!----------------------------------------------------------------------------------------
!
! This file is part of EFTCAMB.
!
! Copyright (C) 2013-2016 by the EFTCAMB authors
!
! The EFTCAMB code is free software;
! You can use it, redistribute it, and/or modify it under the terms
! of the GNU General Public License as published by the Free Software Foundation;
! either version 3 of the License, or (at your option) any later version.
! The full text of the license can be found in the file eftcamb/LICENSE at
! the top level of the EFTCAMB distribution.
!
!----------------------------------------------------------------------------------------



!----------------------------------------------------------------------------------------


module eftcamb_le_horava

    use precision
    use inifile
    use amlutils
    use eftcamb_cache
    use eft_def
    use eftcamb_abstract_model_designer

    implicit none

    private

    public eftcamb_horava

    !----------------------------------------------------------------------------------------
    type, extends ( eftcamb_designer_model ) :: eftcamb_horava

        ! the model selection flag:
        logical   :: horavasolarsystem

        ! the model parameters:
        real(dl)  :: horava_eta
        real(dl)  :: horava_xi
        real(dl)  :: horava_lambda

    contains

        ! initialization of the model:
        procedure :: read_model_selection            => eftcambhoravareadmodelselectionfromfile  
        procedure :: allocate_model_selection        => eftcambhoravaallocatemodelselection      
        procedure :: init_model_parameters           => eftcambhoravainitmodelparameters         
        procedure :: init_model_parameters_from_file => eftcambhoravainitmodelparametersfromfile 
        ! utility functions:
        procedure :: compute_param_number  => eftcambhoravacomputeparametersnumber    
        procedure :: feedback              => eftcambhoravafeedback                   
        procedure :: parameter_names       => eftcambhoravaparameternames             
        procedure :: parameter_names_latex => eftcambhoravaparameternameslatex        
        procedure :: parameter_values      => eftcambhoravaparametervalues            
        ! CAMB related procedures:
        procedure :: compute_background_eft_functions  => eftcambhoravabackgroundeftfunctions   
        procedure :: compute_secondorder_eft_functions => eftcambhoravasecondordereftfunctions  
        procedure :: compute_dtauda                    => eftcambhoravacomputedtauda            
        procedure :: compute_adotoa                    => eftcambhoravacomputeadotoa            
        procedure :: compute_h_derivs                  => eftcambhoravacomputehubbleder         
        procedure :: compute_pi_factors                => eftcambhoravacomputepifactors         
        ! stability procedures:
        procedure :: additional_model_stability        => eftcambhoravaadditionalmodelstability 

    end type eftcamb_horava

    ! ---------------------------------------------------------------------------------------------

contains

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambhoravareadmodelselectionfromfile( self, Ini )

        implicit none

        class(eftcamb_horava)       :: self
        type(tinifile)              :: ini

        ! read model selection flags:
        self%HoravaSolarSystem = ini_read_logical_file( ini, 'HoravaSolarSystem', .false. )

    end subroutine eftcambhoravareadmodelselectionfromfile

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambhoravaallocatemodelselection( self )

        implicit none

        class(eftcamb_horava) :: self

    end subroutine eftcambhoravaallocatemodelselection

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambhoravainitmodelparameters( self, array )

        implicit none

        class(eftcamb_horava)                                  :: self
        real(dl), dimension(self%parameter_number), intent(in) :: array

        real(dl), allocatable, dimension(:)                    :: temp
        integer :: num_params_function, num_params_temp, i

        if ( self%HoravaSolarSystem ) then
            self%Horava_eta    = array(1)
            self%Horava_lambda = array(2)
            self%Horava_xi     = 0.5_dl*self%Horava_eta
        else
            self%Horava_eta    = array(1)
            self%Horava_lambda = array(2)
            self%Horava_xi     = array(3)
        end if

    end subroutine eftcambhoravainitmodelparameters

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambhoravainitmodelparametersfromfile( self, Ini )

        implicit none

        class(eftcamb_horava)          :: self
        type(tinifile)                 :: ini

        self%Horava_eta    = ini_read_double_file( ini, 'Horava_eta'   , 0._dl )
        self%Horava_lambda = ini_read_double_file( ini, 'Horava_lambda', 0._dl )
        if ( self%HoravaSolarSystem ) then
            self%Horava_xi = 0.5_dl*self%Horava_eta
        else
            self%Horava_xi = ini_read_double_file( ini, 'Horava_xi'    , 0._dl )
        end if

    end subroutine eftcambhoravainitmodelparametersfromfile

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambhoravacomputeparametersnumber( self )

        implicit none

        class(eftcamb_horava)  :: self

        if ( self%HoravaSolarSystem ) then
            self%parameter_number = 2
        else
            self%parameter_number = 3
        end if

    end subroutine eftcambhoravacomputeparametersnumber

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambhoravafeedback( self, print_params )

        implicit none

        class(eftcamb_horava)  :: self
        logical, optional      :: print_params

        logical                :: print_params_temp

        ! print general model informations:
        write(*,*)
        write(*,'(a,a)')    '   Model               =  ', self%name
        write(*,'(a,I3)')   '   Number of params    ='  , self%parameter_number

        if ( self%HoravaSolarSystem ) then
            write(*,'(a)')  '   Horava with solar system constraints'
        end if

        ! print the values of the parameters:
        if ( present(print_params) ) then
            print_params_temp = print_params
        else
            print_params_temp = .true.
        end if

        if ( print_params_temp ) then
            write(*,*)
            write(*,'(a23,a,F12.6)') '   Horava_eta          ', '=', self%Horava_eta
            write(*,'(a23,a,F12.6)') '   Horava_lambda       ', '=', self%Horava_lambda
            if ( .not. self%HoravaSolarSystem ) then
                write(*,'(a23,a,F12.6)') '   Horava_xi           ', '=', self%Horava_xi
            end if
        end if

    end subroutine eftcambhoravafeedback

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambhoravaparameternames( self, i, name )

        implicit none

        class(eftcamb_horava)       :: self
        integer     , intent(in)    :: i
        character(*), intent(out)   :: name

        ! check the input index:
        if ( i>self%parameter_number ) then
            write(*,*) 'Illegal index for parameter_names.'
            write(*,*) 'Maximum value is:', self%parameter_number
            call mpistop('EFTCAMB error')
        end if
        ! return the appropriate name:
        if ( i==1 ) then
            name = 'Horava_eta'
            return
        end if
        if ( i==2 ) then
            name = 'Horava_lambda'
            return
        end if
        if ( i==3 .and. self%HoravaSolarSystem ) then
            name = 'Horava_xi'
            return
        end if

    end subroutine eftcambhoravaparameternames

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambhoravaparameternameslatex( self, i, latexname )

        implicit none

        class(eftcamb_horava)       :: self
        integer     , intent(in)    :: i
        character(*), intent(out)   :: latexname

        ! check the input index:
        if ( i>self%parameter_number ) then
            write(*,*) 'Illegal index for parameter_names_latex.'
            write(*,*) 'Maximum value is:', self%parameter_number
            call mpistop('EFTCAMB error')
        end if
        ! return the appropriate name:
        if ( i==1 ) then
            latexname = '\eta_{\rm Ho\v rava}'
            return
        end if
        if ( i==2 ) then
            latexname = '\lambda_{\rm Ho\v rava}'
            return
        end if
        if ( i==3 .and. self%HoravaSolarSystem ) then
            latexname = '\xi_{\rm Ho\v rava}'
            return
        end if

    end subroutine eftcambhoravaparameternameslatex

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambhoravaparametervalues( self, i, value )

        implicit none

        class(eftcamb_horava)       :: self
        integer , intent(in)        :: i
        real(dl), intent(out)       :: value

        ! check the input index:
        if ( i>self%parameter_number ) then
            write(*,*) 'Illegal index for parameter_value.'
            write(*,*) 'Maximum value is:', self%parameter_number
            call mpistop('EFTCAMB error')
        end if
        ! return the appropriate name:
        if ( i==1 ) then
            value = self%Horava_eta
            return
        end if
        if ( i==2 ) then
            value = self%Horava_lambda
            return
        end if
        if ( i==3 .and. self%HoravaSolarSystem ) then
            value = self%Horava_xi
            return
        end if

    end subroutine eftcambhoravaparametervalues

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambhoravabackgroundeftfunctions( self, a, eft_par_cache, eft_cache )

        implicit none

        class(eftcamb_horava)                        :: self
        real(dl), intent(in)                         :: a
        type(eftcamb_parameter_cache), intent(inout) :: eft_par_cache
        type(eftcamb_timestep_cache ), intent(inout) :: eft_cache

        ! compute the EFT functions:
        eft_cache%EFTOmegaV    = self%Horava_eta/( 2._dl +2._dl*self%Horava_xi -self%Horava_eta )
        eft_cache%EFTOmegaP    = 0._dl
        eft_cache%EFTOmegaPP   = 0._dl
        eft_cache%EFTOmegaPPP  = 0._dl
        eft_cache%EFTc         = -( 2._dl*self%Horava_xi -3._dl*self%Horava_lambda )*( eft_cache%Hdot -eft_cache%adotoa**2 )/( 2._dl +2._dl*self%Horava_xi -self%Horava_eta )
        eft_cache%EFTLambda    = -eft_cache%grhov_t + 2._dl*( 3._dl*self%Horava_lambda - 2._dl*self%Horava_xi)*&
            &( 0.5_dl*eft_cache%adotoa**2 + eft_cache%Hdot)/( 2._dl +2._dl*self%Horava_xi -self%Horava_eta )
        eft_cache%EFTcdot      = ( 3._dl*self%Horava_lambda - 2._dl*self%Horava_xi )*&
            &( eft_cache%Hdotdot -4._dl*eft_cache%adotoa*eft_cache%Hdot + 2._dl*eft_cache%adotoa**3 )/( 2._dl +2._dl*self%Horava_xi -self%Horava_eta )
        eft_cache%EFTLambdadot = +2._dl*( 3._dl*self%Horava_lambda -2._dl*self%Horava_xi)*&
            &( eft_cache%Hdotdot -eft_cache%adotoa*eft_cache%Hdot -eft_cache%adotoa**3 )/( 2._dl +2._dl*self%Horava_xi -self%Horava_eta )

    end subroutine eftcambhoravabackgroundeftfunctions

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambhoravasecondordereftfunctions( self, a, eft_par_cache, eft_cache )

        implicit none

        class(eftcamb_horava)                        :: self
        real(dl), intent(in)                         :: a
        type(eftcamb_parameter_cache), intent(inout) :: eft_par_cache
        type(eftcamb_timestep_cache ), intent(inout) :: eft_cache

        ! compute the EFT functions:
        eft_cache%EFTGamma1V  = 0._dl
        eft_cache%EFTGamma1P  = 0._dl
        eft_cache%EFTGamma2V  = 0._dl
        eft_cache%EFTGamma2P  = 0._dl
        eft_cache%EFTGamma3V  = 2._dl*(self%Horava_lambda -self%Horava_xi)/( 2._dl +2._dl*self%Horava_xi -self%Horava_eta )
        eft_cache%EFTGamma3P  = 0._dl
        eft_cache%EFTGamma4V  = 2._dl*self%Horava_xi/( 2._dl +2._dl*self%Horava_xi -self%Horava_eta )
        eft_cache%EFTGamma4P  = 0._dl
        eft_cache%EFTGamma4PP = 0._dl
        eft_cache%EFTGamma5V  = 0._dl
        eft_cache%EFTGamma5P  = 0._dl
        eft_cache%EFTGamma6V  = self%Horava_eta/4._dl/( 2._dl +2._dl*self%Horava_xi -self%Horava_eta )
        eft_cache%EFTGamma6P  = 0._dl

    end subroutine eftcambhoravasecondordereftfunctions

    ! ---------------------------------------------------------------------------------------------
    function eftcambhoravacomputedtauda( self, a, eft_par_cache, eft_cache )

        implicit none

        class(eftcamb_horava)                        :: self
        real(dl), intent(in)                         :: a
        type(eftcamb_parameter_cache), intent(inout) :: eft_par_cache
        type(eftcamb_timestep_cache ), intent(inout) :: eft_cache

        real(dl) :: eftcambhoravacomputedtauda

        real(dl) :: temp

        temp = eft_cache%grhoa2 +a**4*( eft_par_cache%grhov &
            & +3._dl*eft_par_cache%h0_Mpc**2*( (self%Horava_eta +3._dl*self%Horava_lambda-2._dl*self%Horava_xi)/(2._dl*self%Horava_xi+2._dl-self%Horava_eta)))
        eftcambhoravacomputedtauda = sqrt(3/temp)/sqrt(( 2._dl +2._dl*self%Horava_xi -self%Horava_eta )/(3._dl*self%Horava_lambda +2._dl))

    end function eftcambhoravacomputedtauda

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambhoravacomputeadotoa( self, a, eft_par_cache, eft_cache )

        implicit none

        class(eftcamb_horava)                        :: self
        real(dl), intent(in)                         :: a
        type(eftcamb_parameter_cache), intent(inout) :: eft_par_cache
        type(eftcamb_timestep_cache ), intent(inout) :: eft_cache

        eft_cache%grhov_t = ( eft_par_cache%grhov &
            & +3._dl*eft_par_cache%h0_Mpc**2*((self%Horava_eta +3._dl*self%Horava_lambda -2._dl*self%Horava_xi)/(2._dl*self%Horava_xi +2._dl -self%Horava_eta)))*a**2
        eft_cache%adotoa  = sqrt( ( eft_cache%grhom_t +eft_cache%grhov_t )/3._dl )
        eft_cache%adotoa  = eft_cache%adotoa*sqrt(( 2._dl +2._dl*self%Horava_xi -self%Horava_eta )/(3._dl*self%Horava_lambda +2._dl))

    end subroutine eftcambhoravacomputeadotoa

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambhoravacomputehubbleder( self, a, eft_par_cache, eft_cache )

        implicit none

        class(eftcamb_horava)                        :: self
        real(dl), intent(in)                         :: a
        type(eftcamb_parameter_cache), intent(inout) :: eft_par_cache
        type(eftcamb_timestep_cache ), intent(inout) :: eft_cache

        eft_cache%gpiv_t   = -eft_cache%grhov_t
        eft_cache%Hdot     = -0.5_dl*( eft_cache%adotoa**2 +eft_cache%gpresm_t +eft_cache%gpiv_t )
        eft_cache%Hdotdot  = eft_cache%adotoa*( ( eft_cache%grhob_t +eft_cache%grhoc_t)/6._dl +2._dl*( eft_cache%grhor_t +eft_cache%grhog_t)/3._dl ) &
            & +2._dl*eft_cache%adotoa*eft_cache%grhov_t/3._dl &
            & +eft_cache%adotoa*eft_cache%grhonu_tot/6._dl -0.5_dl*eft_cache%adotoa*eft_cache%gpinu_tot -0.5_dl*eft_cache%gpinudot_tot

        eft_cache%Hdot     = eft_cache%Hdot*sqrt(( 2._dl +2._dl*self%Horava_xi -self%Horava_eta )/(3._dl*self%Horava_lambda +2._dl))
        eft_cache%Hdotdot  = eft_cache%Hdotdot*sqrt(( 2._dl +2._dl*self%Horava_xi -self%Horava_eta )/(3._dl*self%Horava_lambda +2._dl))

    end subroutine eftcambhoravacomputehubbleder

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambhoravacomputepifactors( self, a, eft_par_cache, eft_cache )

        implicit none

        class(eftcamb_horava)                        :: self
        real(dl), intent(in)                         :: a
        type(eftcamb_parameter_cache), intent(inout) :: eft_par_cache
        type(eftcamb_timestep_cache ), intent(inout) :: eft_cache

        eft_cache%EFTpiA1  = 0._dl
        eft_cache%EFTpiA2  = 0.5_dl*self%Horava_eta
        eft_cache%EFTpiB1  = 0._dl
        eft_cache%EFTpiB2  = eft_cache%adotoa*self%Horava_eta
        eft_cache%EFTpiC   = 0._dl
        eft_cache%EFTpiD1  = 0.5_dl*( 3._dl*self%Horava_lambda -2._dl*self%Horava_xi)*( eft_cache%adotoa**2 -eft_cache%Hdot ) + 0.5_dl*self%Horava_eta*( eft_cache%adotoa**2 +eft_cache%Hdot )
        eft_cache%EFTpiD2  = 0.5_dl*self%Horava_lambda*(1._dl+self%Horava_xi)
        eft_cache%EFTpiE   = 0.5_dl*eft_cache%k**2*self%Horava_lambda*( 1._dl +self%Horava_xi )*eft_cache%k*eft_cache%z + 0.5_dl*eft_cache%k*self%Horava_xi*eft_cache%dgq

    end subroutine eftcambhoravacomputepifactors

    ! ---------------------------------------------------------------------------------------------
    function eftcambhoravaadditionalmodelstability( self, a, eft_par_cache, eft_cache )

        implicit none

        class(eftcamb_horava)                        :: self
        real(dl), intent(in)                         :: a
        type(eftcamb_parameter_cache), intent(inout) :: eft_par_cache
        type(eftcamb_timestep_cache ), intent(inout) :: eft_cache

        logical :: eftcambhoravaadditionalmodelstability

        eftcambhoravaadditionalmodelstability = .true.

        if ( self%Horava_lambda > -2._dl/3._dl .and. self%Horava_lambda < 0._dl ) then
            eftcambhoravaadditionalmodelstability = .false.
        end if
        if ( self%Horava_eta < 0._dl .or. self%Horava_eta > 2._dl*self%Horava_xi +2._dl ) then
            eftcambhoravaadditionalmodelstability = .false.
        end if

    end function eftcambhoravaadditionalmodelstability

    ! ---------------------------------------------------------------------------------------------

end module eftcamb_le_horava