09p2_Designer_mc_quintessence.f90

Go to the documentation of this file.

!----------------------------------------------------------------------------------------
!
! This file is part of EFTCAMB.
!
! Copyright (C) 2013-2016 by the EFTCAMB authors
!
! The EFTCAMB code is free software;
! You can use it, redistribute it, and/or modify it under the terms
! of the GNU General Public License as published by the Free Software Foundation;
! either version 3 of the License, or (at your option) any later version.
! The full text of the license can be found in the file eftcamb/LICENSE at
! the top level of the EFTCAMB distribution.
!
!----------------------------------------------------------------------------------------



!----------------------------------------------------------------------------------------


module eftcamb_designer_mc_quintessence

    use precision
    use inifile
    use amlutils
    use eftcamb_neutral_parametrization_1d
    use eftcamb_constant_parametrization_1d
    use eftcamb_linear_parametrizations_1d
    use eftcamb_power_law_parametrizations_1d
    use eftcamb_exponential_parametrizations_1d
    use eftcamb_cpl_parametrizations_1d
    use eftcamb_jbp_parametrizations_1d
    use eftcamb_turning_point_parametrizations_1d
    use eftcamb_taylor_parametrizations_1d
    use eftcamb_pure_eft_std

    implicit none

    private

    public eftcamb_des_mc_quint

    !----------------------------------------------------------------------------------------
    type, extends ( eftcamb_std_pure_eft ) :: eftcamb_des_mc_quint

    contains

        ! initialization of the model:
        procedure :: allocate_model_selection  => eftcambdesmc5eallocatemodelselection      
        ! utility functions:
        procedure :: feedback                  => eftcambdesmc5efeedback                    

    end type eftcamb_des_mc_quint

    ! ---------------------------------------------------------------------------------------------

contains

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambdesmc5eallocatemodelselection( self )

        implicit none

        class(eftcamb_des_mc_quint)                       :: self

        ! allocate wDE:
        if ( allocated(self%PureEFTwDE) ) deallocate(self%PureEFTwDE)
        select case ( self%EFTwDE )
            case(0)
                allocate( wde_lcdm_parametrization_1d::self%PureEFTwDE )
            case(1)
                allocate( constant_parametrization_1d::self%PureEFTwDE )
            case(2)
                allocate( cpl_parametrization_1d::self%PureEFTwDE )
                call self%PureEFTwDE%set_param_names( ['EFTw0', 'EFTwa'], ['w_0', 'w_a'] )
            case(3)
                allocate( jbp_parametrization_1d::self%PureEFTwDE )
                call self%PureEFTwDE%set_param_names( ['EFTw0', 'EFTwa', 'EFTwn'], [ 'w_0', 'w_a', 'n  ' ] )
            case(4)
                allocate( turning_point_parametrization_1d::self%PureEFTwDE )
                call self%PureEFTwDE%set_param_names( ['EFTw0 ', 'EFTwa ', 'EFTwat'], ['w_0', 'w_a', 'a_t'] )
            case(5)
                allocate( taylor_parametrization_1d::self%PureEFTwDE )
                call self%PureEFTwDE%set_param_names( ['EFTw0', 'EFTwa', 'EFTw2', 'EFTw3'], ['w_0', 'w_a', 'w_2', 'w_3'] )
            case default
                write(*,'(a,I3)') 'No model corresponding to EFTwDE =', self%EFTwDE
                write(*,'(a)')    'Please select an appropriate model.'
        end select
        ! allocate Omega:
        if ( allocated(self%PureEFTOmega) ) deallocate(self%PureEFTOmega)
        allocate( zero_parametrization_1d::self%PureEFTOmega )
        ! allocate Gamma1:
        if ( allocated(self%PureEFTGamma1) ) deallocate(self%PureEFTGamma1)
        allocate( zero_parametrization_1d::self%PureEFTGamma1 )
        ! allocate Gamma2:
        if ( allocated(self%PureEFTGamma2) ) deallocate(self%PureEFTGamma2)
        allocate( zero_parametrization_1d::self%PureEFTGamma2 )
        ! allocate Gamma3:
        if ( allocated(self%PureEFTGamma3) ) deallocate(self%PureEFTGamma3)
        allocate( zero_parametrization_1d::self%PureEFTGamma3 )
        ! allocate Gamma4:
        if ( allocated(self%PureEFTGamma4) ) deallocate(self%PureEFTGamma4)
        allocate( zero_parametrization_1d::self%PureEFTGamma4 )
        ! allocate Gamma5:
        if ( allocated(self%PureEFTGamma5) ) deallocate(self%PureEFTGamma5)
        allocate( zero_parametrization_1d::self%PureEFTGamma5 )
        ! allocate Gamma6:
        if ( allocated(self%PureEFTGamma6) ) deallocate(self%PureEFTGamma6)
        allocate( zero_parametrization_1d::self%PureEFTGamma6 )

        ! initialize the names:
        call self%PureEFTOmega%set_name ( 'EFTOmega' , '\Omega'       )
        call self%PureEFTwDE%set_name   ( 'EFTw'     , 'w'            )
        call self%PureEFTGamma1%set_name( 'EFTGamma1', '\gamma^{(1)}' )
        call self%PureEFTGamma2%set_name( 'EFTGamma2', '\gamma^{(2)}' )
        call self%PureEFTGamma3%set_name( 'EFTGamma3', '\gamma^{(3)}' )
        call self%PureEFTGamma4%set_name( 'EFTGamma4', '\gamma^{(4)}' )
        call self%PureEFTGamma5%set_name( 'EFTGamma5', '\gamma^{(5)}' )
        call self%PureEFTGamma6%set_name( 'EFTGamma6', '\gamma^{(6)}' )

    end subroutine eftcambdesmc5eallocatemodelselection

    ! ---------------------------------------------------------------------------------------------
    subroutine eftcambdesmc5efeedback( self, print_params )

        implicit none

        class(eftcamb_des_mc_quint)  :: self
        logical, optional            :: print_params

        ! print general model informations:
        write(*,*)
        write(*,'(a,a)')    '   Model               =  ', self%name
        write(*,'(a,I3)')   '   Number of params    ='  , self%parameter_number

        ! print model functions informations:
        write(*,*)
        if ( self%EFTwDE             /= 0 ) write(*,'(a,I3)') '   EFTwDE              =', self%EFTwDE

        write(*,*)
        ! print functions informations:
        call self%PureEFTwDE%feedback( print_params )

    end subroutine eftcambdesmc5efeedback

    ! ---------------------------------------------------------------------------------------------

end module eftcamb_designer_mc_quintessence

!----------------------------------------------------------------------------------------